FamousWriterをご使用の皆様へ

 幻想郷のソースが見たいとのご要望がございましたので
FamousWriterユーザー様のお役に立つか分かりませんが
こんなものでよければご参考になさってください。

個別の細かな質問に対しましては、出来るだけ対応したいのですが
何分多忙なため時間がかかると思いますので、
ご了承ください。

他のユーザー様とも情報を共有したいので、ユーザー書き込み帳にて
ご質問ください。
ご協力お願いいたします。

今回はセーブ画面のソースを公開します。
今後もご要望があればのせたいと思います。

本文のソースは勝手ながら公開出来ませんので、質問のみと
させていただきます。

 FmWrPlin________

 

 

########################################

# 幻想郷　　セーブ画面設定の章

########################################

 

#　※印の箇所は改造または追記項目

 

#---------------------------------------------------------------

# SAVE画面　6ページ仕様

#---------------------------------------------------------------

 

# 変数名が本編とカブらないよう注意してください

# 使用してる変数は以下の通り

# %MaxPage, %Page, %Selected, %file

# $Line, $return

 

#---------------------------------------------------------------

# 初期設定

#---------------------------------------------------------------

 

# *ImageFormat = bmp;

# 最大ページ数

%MaxPage     = 6;

# 現在のページ／※前回開いていたページから再開

%CurrentPage = %!NowOpenPage

 

# ※本編作動時のため最上層レイヤーに背景表示

&Layer.No = 9;&Layer.Pos = 0, 0;&Layer.Load = /image/backg/datebgsave.jpg;&Draw = 704;

 

#---------------------------------------------------------------

# ページの表示

#---------------------------------------------------------------

 

@b1;

# ボタンの位置※

&LdSelectButton=  620, 20, /image/txt_btn_ico/dataseat.jpg : %Selected = 1;

# ページとボタン番号からファイル名を得る

%file = %CurrentPage;

%file * 10;

%file + 1;

# セーブデータをバッファに読み込む

&LoadBuffer = %file;

# ボタン描画サブへ※

$return = @b2; &Jmp = @DrawButton;

@b2;

&LdSelectButton= 620, 300, /image/txt_btn_ico/dataseat.jpg : %Selected = 2;

%file = %CurrentPage; %file * 10; %file + 2;

&LoadBuffer = %file; $return = @b3; &Jmp = @DrawButton;

@b3;

&LdSelectButton= 415, 20, /image/txt_btn_ico/dataseat.jpg : %Selected = 3;

%file = %CurrentPage; %file * 10; %file + 3;

&LoadBuffer = %file; $return = @b4; &Jmp = @DrawButton;

 

@b4;

&LdSelectButton= 415, 300, /image/txt_btn_ico/dataseat.jpg : %Selected = 4;

%file = %CurrentPage; %file * 10; %file + 4;

&LoadBuffer = %file; $return = @b5; &Jmp = @DrawButton;

 

@b5;

&LdSelectButton= 215, 20, /image/txt_btn_ico/dataseat.jpg : %Selected = 5;

%file = %CurrentPage; %file * 10; %file + 5;

&LoadBuffer = %file; $return = @b6; &Jmp = @DrawButton;

 

@b6;

&LdSelectButton= 215, 300, /image/txt_btn_ico/dataseat.jpg : %Selected = 6;

%file = %CurrentPage; %file * 10; %file + 6;

&LoadBuffer = %file; $return = @c1; &Jmp = @DrawButton;

 

@c1;

# キャンセルボタン※

&LdSelectButton= 82,530, /image/txt_btn_ico/back.jpg : %Selected = 10;

#&b.padding = 12,6;

#&b.Font-Size = 12; &b.Line-Height = 12;

#&b.Color = #ffffff; &b.Shadow = 333333;

#&b.text = 戻る;

# ページ表示／※非表示

#&LdSelectButton= 50,550, /image/txt_btn_ico/cancel.jpg : %Selected = 19;

#&ButtonEnable= no;

#&b.padding = 12,6;

#&b.Font-Size = 12; &b.Line-Height = 12;

#$Line = Ｐａｇｅ：; $Line + %CurrentPage; $Line + ／; $Line + %MaxPage;

#&b.text = $Line;

# ページめくりボタン／※１ページ毎に選択表示

&LdSelectButton= 77,50, /image/txt_btn_ico/shiori1.jpg : %Selected = 11; 

&LdSelectButton= 77,100, /image/txt_btn_ico/shiori2.jpg : %Selected = 12; 

&LdSelectButton= 77,150, /image/txt_btn_ico/shiori3.jpg : %Selected = 13; 

&LdSelectButton= 77,200, /image/txt_btn_ico/shiori4.jpg : %Selected = 14; 

&LdSelectButton= 77,250, /image/txt_btn_ico/shiori5.jpg : %Selected = 15; 

&LdSelectButton= 77,300, /image/txt_btn_ico/shiori6.jpg : %Selected = 16; 

 

 

@select;

# 選択肢を表示

&SelectButton = 701;

 

#---------------------------------------------------------------

# 選択後の処理

#---------------------------------------------------------------

 

# ページとボタン番号からファイル名を得る

%file = %CurrentPage; %file * 10; %file + %Selected;

# セーブボタンだったら実際にセーブする

? %Selected < 9  : &SaveLocal = %file;

# キャンセルボタン

? %Selected = 10 : &Jmp = @cancel;

# ページめくりボタン／※ページ選択後の処理

? %Selected = 11 : %CurrentPage =1;

? %Selected = 11 : &Jmp = @b1;

? %Selected = 12 : %CurrentPage =2;

? %Selected = 12 : &Jmp = @b1;

? %Selected = 13 : %CurrentPage =3;

? %Selected = 13 : &Jmp = @b1;

? %Selected = 14 : %CurrentPage =4;

? %Selected = 14 : &Jmp = @b1;

? %Selected = 15 : %CurrentPage =5;

? %Selected = 15 : &Jmp = @b1;

? %Selected = 16 : %CurrentPage =6;

? %Selected = 16 : &Jmp = @b1;

&Jmp = @b1;

 

 

@cancel

#セーブはキャンセルされました。

&DialogFileEnd;

 

#---------------------------------------------------------------

# ボタン描画サブルーチン

#---------------------------------------------------------------

 

@DrawButton;

# セーブデータをバッファに読み込めてるか

%LBStatus = &LoadBuffer.Status;

# セーブデータがなければ「未使用」にする※

?%LBStatus= 0 : $Line = ;

# セーブデータがあれば、日付を読んで文字変数に代入※

?%LBStatus= 1 : $Line = &LoadBuffer.ShortDate;

?%LBStatus= 1 : $Line + /;

?%LBStatus= 1 : $Line + &LoadBuffer.ShortTime;

?%LBStatus= 1 : $Line + /;

?%LBStatus= 1 : $Line + &LoadBuffer.Text;

# セーブデータがあれば、画面のスクリーンショットをボタンに表示※

?%LBStatus= 1 : &b.LdCG = &LoadBuffer.Img,2,2;

# ボタンの文字の表示位置などを設定※

&b.padding = 150,5,5,5;

&b.Font-Size = 13;

&b.Line-Height = 18;

# ボタンの文字の色

&b.Color = 333333; &b.Shadow = 999999;

# 読み込んだ文字情報をボタンに文字として描く

&b.text = $Line;

 

#---------------------------------------------------------------

# ※カレントページの保存

#---------------------------------------------------------------

 

@current

%!NowOpenPage = %CurrentPage

 

 

# 戻る

&Jmp = $return;